The Visitor Pattern – Part 1 – Page 3 – The Art of Delphi Programming

We can now derive from TShapeVisitor to achieve the different behaviour. For instance, to draw on a TCanvas we would have something like this:

unit uCanvasVisitorGoF;

interface

uses
  uVisitorGoF, Graphics, Types;

type
  TShapeVisitorCanvas = class(TShapeVisitor)
  private
    FCanvas: TCanvas;
    property Canvas: TCanvas read FCanvas;
  protected
    function TransformPoint(X, Y: Double): TPoint; virtual;
  public
    constructor Create(ACanvas: TCanvas);
    procedure VisitShapeCircle(Instance: TShapeCircle); override;
    procedure VisitShapeRectangle(Instance: TShapeRectangle); override;
  end;

implementation

constructor TShapeVisitorCanvas.Create(ACanvas: TCanvas);
begin
  inherited Create;
  FCanvas := ACanvas;
end;

function TShapeVisitorCanvas.TransformPoint(X, Y: Double): TPoint;
begin
  Result := Point(Round(X), Round(Y));
end;

procedure TShapeVisitorCanvas.VisitShapeCircle(Instance: TShapeCircle);
var
  P1: TPoint;
  P2: TPoint;
begin
  P1 := TransformPoint(Instance.CenterX - Instance.Radius,
                       Instance.CenterY - Instance.Radius);
  P2 := TransformPoint(Instance.CenterX + Instance.Radius,
                       Instance.CenterY + Instance.Radius);
  Canvas.Ellipse(P1.X, P1.Y, P2.X, P2.Y);
end;

procedure TShapeVisitorCanvas.VisitShapeRectangle(Instance: TShapeRectangle);
var
  P1: TPoint;
  P2: TPoint;
begin
  P1 := TransformPoint(Instance.X0, Instance.Y0);
  P2 := TransformPoint(Instance.X1, Instance.Y1);
  Canvas.Rectangle(P1.X, P1.Y, P2.X, P2.Y);
end;

end.

unit uCanvasVisitorGoF;

interface

uses

uVisitorGoF, Graphics, Types;

type

TShapeVisitorCanvas = class(TShapeVisitor)

private

FCanvas: TCanvas;

property Canvas: TCanvas read FCanvas;

protected

function TransformPoint(X, Y: Double): TPoint; virtual;

public

constructor Create(ACanvas: TCanvas);

procedure VisitShapeCircle(Instance: TShapeCircle); override;

procedure VisitShapeRectangle(Instance: TShapeRectangle); override;

end;

implementation

constructor TShapeVisitorCanvas.Create(ACanvas: TCanvas);

begin

inherited Create;

FCanvas := ACanvas;

end;

function TShapeVisitorCanvas.TransformPoint(X, Y: Double): TPoint;

begin

Result := Point(Round(X), Round(Y));

end;

procedure TShapeVisitorCanvas.VisitShapeCircle(Instance: TShapeCircle);

var

P1: TPoint;

P2: TPoint;

begin

P1 := TransformPoint(Instance.CenterX - Instance.Radius,

Instance.CenterY - Instance.Radius);

P2 := TransformPoint(Instance.CenterX + Instance.Radius,

Instance.CenterY + Instance.Radius);

Canvas.Ellipse(P1.X, P1.Y, P2.X, P2.Y);

end;

procedure TShapeVisitorCanvas.VisitShapeRectangle(Instance: TShapeRectangle);

var

P1: TPoint;

P2: TPoint;

begin

P1 := TransformPoint(Instance.X0, Instance.Y0);

P2 := TransformPoint(Instance.X1, Instance.Y1);

Canvas.Rectangle(P1.X, P1.Y, P2.X, P2.Y);

end;

end.

It is worth to mention that the units Graphics and Types are only used in the new visitor unit. There is no reference to them in the unit describing the shapes.

The other visitors can be implemented in a similar way keeping all the specific stuff (Inifiles, OpenGL, XML) inside the visitor unit. This allows to only include the visitors we actually need and doesn’t pollute our uses clause with units we don’t want in our application.

Author: Uwe Raabe

Addicted to Pascal/Delphi since the late 70's View all posts by Uwe Raabe

One thought on “The Visitor Pattern – Part 1”

Jan says:

August 17, 2010 at 00:26

Thanks for an excellent article on the visitor pattern. I have heard a lot of talk regarding patterns, but all very abstract in its descriptions. This one really makes it easy to understand.

Jan

Comments are closed.